zrong's Blog » AS3

Signals框架介绍（三）原生事件

zrong — Mon, 23 Jan 2012 15:16:15 +0000

注意：本文参考An introduction to AS3 Signals写成，但不是翻译，有增删改。

第一部分：Signals框架介绍（一）基本用法
第二部分：Signals框架介绍（二）高级事件

原生事件

为了达到替换AS3事件机制的目的，Signals当然包含了对AS3原生事件的支持。这依赖于NativeSignal类。

下面的范例演示了如何在Stage上添加单击事件。由于一看就懂，这里就不废话解释了。

[NativeSignalSample.as]

^?Download NativeSignalSample.as

package
{
import flash.display.Sprite;
import flash.events.MouseEvent;
import org.osflash.signals.natives.NativeSignal;
 
[SWF(width=500,height=300,frameRate=30,backgroundColor=0xFFFFFF)]
/**
 * 测试原生事件
 * @author zrong(zengrong.net)
 */
public class NativeSignalSample extends Sprite 
{
    public function NativeSignalSample()
    {
        _click = new NativeSignal(this.stage, MouseEvent.CLICK, MouseEvent);
        _click.add(handler_click);
        //测试只发生一次的点击事件
        //_click.addOnce(handler_click);
    }
 
    private var _click:NativeSignal;
 
    private function handler_click($evt:MouseEvent):void
    {
        trace('currentTarget：',$evt.currentTarget);
        trace('target：',$evt.target);
    }
}
}

其它资料

An introduction to AS3 Signals（本文的参考）
AS3 Signals Tutorial（一个非常棒的视频教程）
更多的文章，与其它框架(PureMVC,Robotlegs,Flex)的连用
Signals的作者关于AS3事件机制的3篇吐槽文之一,之二,之三

Signals框架介绍（二）高级事件

zrong — Mon, 23 Jan 2012 14:28:32 +0000

注意：本文参考An introduction to AS3 Signals写成，但不是翻译，有增删改。

第一部分：Signals框架介绍（一）基本用法
第三部分：Signals框架介绍（三）原生事件

也许你现在又想起了AS3内置事件框架的好处，希望使用currentTarget？或者希望支持冒泡？OK，Signals也能满足你那多变的心……（貌似是我自己多变罢了ˇ^ˇ）

高级事件

使用DeluxeSignal可以实现更高级的事件传递。还是基于闹钟的例子进行修改，将原来AlarmClock中的Signal改为DeluxSignal：

[AlarmClock.as]

^?View Code ACTIONSCRIPT

public function AlarmClock()
{
    //将自己作为引用传递给DeluxeSignal，同时增加GenericEvent的传递
    alarm = new DeluxeSignal(this, GenericEvent, Date);
}
 
public var alarm:DeluxeSignal;
 
public function ring():void
{
    alarm.dispatch(new GenericEvent(), new Date());
}

修改Wakeup.as中的处理器函数，让它能够接受到传递的2个参数。

[Wakeup.as]

^?View Code ACTIONSCRIPT

private function handler_ring($evt:GenericEvent, $date:Date):void
{
    trace('currentTarget：',$evt.currentTarget);
    trace('target：',$evt.target);
    trace('signal：',$evt.signal);
    trace('起床了！！！也不看看几点了：'+$date.toString());
}

在这里出现的GenericEvent，并非继承自flash.events.Event，而是实现了Signals自己的IEvent接口，与AS3的事件机制毫无关系。取一个貌似兄弟的名称，是为了方便大家理解罢了。它所提供的currentTarget和target属性，也是由IEvent自身提供。

运行修改后的例子，可以看到如下输出：

[trace] currentTarget： [object AlarmClock]
[trace] target： [object AlarmClock]
[trace] signal： [object DeluxeSignal]
[trace] 起床了！！！也不看看几点了：Mon Jan 23 17:07:16 GMT+0800 2012

现在，是不是可以对currentTarget“为所欲为”了呢？

冒泡事件

Signals一样可以冒泡，而且并不依赖AS3自带的事件机制。当然，发送和接收冒泡事件的对象必须处于显示列表中。

为了让AlarmClock能够被加入显示列表，我们让AlarmClock继承Sprite。而抛出冒泡事件就非常简单，只需要在实例化GenericEvent的同时传递true参数即可。看看AlarmClock类被修改的部分吧：

[AlarmClock.as]

^?View Code ACTIONSCRIPT

public class AlarmClock extends Sprite
{
    public function ring():void
    {
        alarm.dispatch(new GenericEvent(true), new Date());
    }
}

接收事件的类，必须实现IBubbleEventHandler接口，在onEventBubbled中处理冒泡事件。同时，要将\_alarm实例加入显示列表。

为了方便查看冒泡效果，可以将addOnce所在的一行注释掉，只接收冒泡事件。

[Wakeup.as]

^?View Code ACTIONSCRIPT

public class Wakeup extends Sprite implements IBubbleEventHandler
{
    public function Wakeup()
    {
        _alarm  = new AlarmClock();
        addChild(_alarm);
        //_alarm.alarm.addOnce(handler_ring);
        _alarm.ring();
    }
 
    public function onEventBubbled($evt:IEvent):Boolean
    {
        trace('冒泡 currentTarget：',$evt.currentTarget);
        trace('冒泡 target：',$evt.target);
        trace('冒泡 signal：',$evt.signal);
        //返回false代表不再继续冒泡
        return false;
    }
}

运行修改后的例子，可以看到如下输出：

[trace] 冒泡 currentTarget： [object Wakeup]
[trace] 冒泡 target： [object AlarmClock]
[trace] 冒泡 signal： [object DeluxeSignal]

完整的类

[AlarmClock.as]

^?Download AlarmClock.as

package
{
import flash.display.Sprite;
import org.osflash.signals.Signal;
import org.osflash.signals.DeluxeSignal;
import org.osflash.signals.events.GenericEvent;
 
/**
* Signals闹钟范例
* @author Aiden Tailor(http://www.developria.com/2010/10/an-introduction-to-as3-signals.html)
* @author zrong(zengrong.net)
*/
 
public class AlarmClock extends Sprite
{
    public function AlarmClock()
    {
        alarm = new DeluxeSignal(this, GenericEvent, Date);
    }
 
    public var alarm:DeluxeSignal;
 
    public function ring():void
    {
        //使用冒泡的方式发布闹钟的响铃事件
        alarm.dispatch(new GenericEvent(true), new Date());
    }
}
}

[Wakeup.as]

^?Download Wakeup.as

package
{
import flash.display.Sprite;
import org.osflash.signals.events.GenericEvent;
import org.osflash.signals.events.IBubbleEventHandler;
import org.osflash.signals.events.IEvent;
 
[SWF(width=500,height=300,frameRate=30,backgroundColor=0xFFFFFF)]
/**
 * 测试闹钟
 * @author Aiden Tailor(http://www.developria.com/2010/10/an-introduction-to-as3-signals.html)
 * @author zrong(zengrong.net)
 */
public class Wakeup extends Sprite implements IBubbleEventHandler
{
    public function Wakeup()
    {
        _alarm  = new AlarmClock();
        addChild(_alarm);
        _alarm.alarm.addOnce(handler_ring);
        _alarm.ring();
    }
 
    private var _alarm:AlarmClock;
 
    private function handler_ring($evt:GenericEvent, $date:Date):void
    {
        trace('currentTarget：',$evt.currentTarget);
        trace('target：',$evt.target);
        trace('signal：',$evt.signal);
        trace('起床了！！！也不看看几点了：'+$date.toString());
    }
 
    public function onEventBubbled($evt:IEvent):Boolean
    {
        trace('冒泡 currentTarget：',$evt.currentTarget);
        trace('冒泡 target：',$evt.target);
        trace('冒泡 signal：',$evt.signal);
        //返回false代表不再继续冒泡
        return false;
    }
}
}

Signals框架介绍（一）基本用法

zrong — Fri, 20 Jan 2012 10:16:19 +0000

注意：本文参考An introduction to AS3 Signals写成，但不是翻译，有增删改。

第二部分：Signals框架介绍（二）高级事件
第三部分：Signals框架介绍（三）原生事件

Signals是一个基于AS3的轻量级事件框架，它被设计用来代替AS3内置的Event框架。

为什么我们要放弃Event框架，改用Signals呢？原因主要有以下几点：

使用AS3内置的Event框架，必须继承EventDispatcher或者自行实现IEventDispatcher，而Signals使用组合，可以避免继承；
使用AS3内置框架在事件中实现值的传递，必须自定义事件类才可以。而Signals可以方便的实现多个强类型值的传递；
Signals不使用字符串来区分不同的事件，而是使用实例;
Signals的速度更快，据说是AS3内置事件机制的4倍。

来看个简单的例子吧，这个例子中的闹钟会叫我们起床。此范例部分源码来自An introduction to AS3 Signals

基本用法

先看看闹钟类AlarmClock.as

^?View Code ACTIONSCRIPT

package
{
import org.osflash.signals.Signal;
 
/**
* Signals闹钟范例
* @author Aiden Tailor(http://www.developria.com/2010/10/an-introduction-to-as3-signals.html)
* @author zrong(zengrong.net)
*/
 
public class AlarmClock
{
    public function AlarmClock()
    {
        alarm = new Signal();
    }
 
    /**
     * 声明一个Signal实例用来发送Signal
     */
    public var alarm:Signal;
 
    public function ring():void
    {
        //发布闹钟的响铃事件
        alarm.dispatch();
    }
}
}

再来看看起床类Wakeup.as

^?View Code ACTIONSCRIPT

package
{
import flash.display.Sprite;
 
[SWF(width=500,height=300,frameRate=30,backgroundColor=0xFFFFFF)]
/**
 * 测试闹钟
 * @author Aiden Tailor(http://www.developria.com/2010/10/an-introduction-to-as3-signals.html)
 * @author zrong(zengrong.net)
 */
public class Wakeup extends Sprite
{
    public function Wakeup()
    {
        _alarm  = new AlarmClock();
 
        //向alarm注册事件，这里不需要提供任何的事件名称。因为alarm就是一个确定的Signal实例。
        _alarm.alarm.add(handler_ring);
 
        //使用addOnce，让alarm在事件收到一次后立即取消
        //_alarm.alarm.addOnce(handler_ring);
 
        _alarm.ring();
        _alarm.ring();
    }
 
    private var _alarm:AlarmClock;
 
    /**
     * 由于我们并没有在事件中传递参数，因此这里的方法也不需要提供任何参数。
     */
    private function handler_ring():void
    {
        trace('起床了！！！');
    }
}
}

在进行事件注册的时候，我们使用的是AlarmClock的public属性alarm。在面向对象编程中，这种方式是不可取的。但我们现在只是个范例对么？不要要求那么严格好不好？

当然，如果你知道在AS3中，使用get方法会比直接使用public属性的性能低不少，或许你也会让这种“不规范”的编程方法延续下去？

取消事件注册

如果运行这个范例，应该可以看到2条“起床了！！！”的trace信息。然后，取消addOnce一行的注释，并注释掉add那行，让它们变成这样：

^?View Code ACTIONSCRIPT

public function Wakeup()
{
    _alarm  = new AlarmClock();
 
    //向alarm注册事件，这里不需要提供任何的事件名称。因为alarm就是一个确定的Signal实例。
    //_alarm.alarm.add(handler_ring);
 
    //使用addOnce，让alarm在事件收到一次后立即取消
    _alarm.alarm.addOnce(handler_ring);
 
    _alarm.ring();
    _alarm.ring();
}

再次运行范例，应该只能看到1条trace信息了。你可以把这种现象理解成原来的AS事件机制中的removeEventDispatcher被自动执行了。

当然，手动移除也是可以的。如果你使用的是add方法注册，可以使用下面的方法来移除事件的注册。

^?View Code ACTIONSCRIPT

_alarm.alarm.remove(handler_ring);
_alarm.alarm.removeAll();

传递参数

看看传递参数有多简单吧……修改AlarmClock.as中的相关代码：

^?View Code ACTIONSCRIPT

public function AlarmClock()
{
    //让我们传递一个AS3的标准Date对象吧，让那个懒虫知道现在几点
    alarm = new Signal(Date);
}
 
public function ring():void
{
    //把当前的时间发出去
    alarm.dispatch(new Date());
}

再修改Wakeup.as中的相关代码：

^?View Code ACTIONSCRIPT

private function handler_ring($date:Date):void
{
    trace('起床了！！！也不看看几点了：'+$date.toString());
}

就这样，不需要该死的继承Event和重写clone()了，是不是很清净呢？

将图像的透明区域转换为Alpha通道原理

zrong — Tue, 27 Sep 2011 01:56:56 +0000

在Sprite Sheep Editor中，使用了这样的一个小技术（思路来自这里）：将透明图像的Alpha通道转换成黑白（灰度）图像，然后与正常图像拼合成一张大图，再存储成JPEG格式。

这方法其实是一个折中方案。因为JPEG格式是不支持透明的，很多时候为了获得透明效果，我们只能使用PNG格式。但PNG是无损压缩的，在图像尺寸上没有优势。如果将Alpha通道转换成黑白图并保存到JPEG图像中，就能大幅降低最终的图像文件大小。

在我的测试中，一个2000×3300的32位带Alpha通道的PNG图像文件大小为2MB，转换为4000×3300（因为拼合了黑白图片，宽度增加一倍）70%压缩比的JPEG后，文件大小为1.1MB。

当然，转换后的JPEG文件画质比PNG要稍差一些。这可以通过调整压缩比得到一定程度的改善。

要将图像的Alpha通道转换为黑白图像，在AS3中很容易：

^?View Code ACTIONSCRIPT

var __p:Point = new Point(0,0);
_channelBmd = new BitmapData(_bmd.width, _bmd.height, true, 0x00000000);
_channelBmd.fillRect(_bmd.rect, 0xff000000);
_channelBmd.copyChannel(_bmd, _bmd.rect, __p, 8, 1);
_channelBmd.copyChannel(_bmd, _bmd.rect, __p, 8, 2);
_channelBmd.copyChannel(_bmd, _bmd.rect, __p, 8, 4)

这些代码将 _bmd的Alpha通道信息分别复制到 _channelBmd的红绿蓝通道中，最终合成了一张代表Alpha通道的灰度图。

但是，并不是所有语言都有“通道”这个概念。其实AS3中的“通道”（包括Photoshop中的）就是在颜色中的红绿蓝值而已，我们可以手工把ARGB颜色中的Alpha分离出来，将它们组成RGB颜色。这是AS3的实现：

^?View Code ACTIONSCRIPT

_pixelBmd = new BitmapData(_bmd.width, _bmd.height, false);
for(var i:int=0;i<_bmd.height;i++)
{
    var __str:String = '';
    for(var j:int=0;j<_bmd.width;j++)
    {
        var __pixel:int = _bmd.getPixel32(j,i);
        //分离ARGB颜色中的alpha值，alpha处于32位的最前面8位
        var __alpha:int = $argb >> 24 & 0xFF;
        var __argbstr:String = __alpha == 0 ? '00' : __alpha.toString(16);
        __str += __argbstr + ' ';
        //利用alpha的值合并成RGB颜色值，因为不需要透明，因此24位即可
        __pixel = __alpha << 16 | __alpha << 8 | __alpha;
        _pixelBmd.setPixel(j,i, __pixel);
    }
    //如果你的屏幕足够宽，可以看到一个字符画，内容你猜猜？
    trace(__str);
}

这是JAVA的实现，当然，也可以用RGBImageFilter来做这件事：

^?View Code JAVA

public BufferedImage convertImage(BufferedImage $image)
{
    _img = $image;
    _w = _img.getWidth();
    _h = _img.getHeight();
    _sourceARGB = _img.getRGB(0, 0, _w, _h, null, 0, _w);
 
    BufferedImage __image = new BufferedImage(_w, _h, BufferedImage.TYPE_INT_RGB);
    int[] __destARGB = new int[_sourceARGB.length];
    System.out.println("所有数组的长度："+_sourceARGB.length);
    for(int i=0;i<_sourceARGB.length;i++)
    {
        int __alpha = _sourceARGB[i] >> 24 & 0xFF;
        __destARGB[i] = __alpha << 16 | __alpha << 8 | __alpha;
    }
    __image.setRGB(0, 0, _w, _h, __destARGB, 0, _w);
    return __image;
}

一个AS3实现的范例：

Note: There is a file embedded within this post, please visit this post to download the file.

使用Embed标签在AS3项目中嵌入字体

zrong — Tue, 06 Sep 2011 09:24:03 +0000

2011年9月10日更新：根据网友zszen的回复，找到这样几篇更详细的文章：

source on github

关于嵌入字体，其实Embed fonts这篇文章已经很详细的介绍了。但这篇文章有这样几个问题：

它是针对Flex开发者的，纯AS开发者看起来未免不爽；
没有讲解怎么使用在Flash IDE中嵌入的字体；
嵌入字体就那么点东西，其实不值得花功夫读这一大篇鸟语（介是偷懒……）

那我就把要点总结下……

配合Flash IDE使用

我现在开始讨厌Flash IDE，因为它实在太慢，而且跳版本不兼容。但如果希望可视化的控制嵌入的字体中的文本，还必须使用Flash CS5。

下面是Flash CS5嵌入字体的两张截图。

这个界面很直观，但其实我们可以用更直观的方式（控制unicodeRange的方式，当然，这个“直观”只是对程序员来说），后面会讲到。

图中的“传统”和“TLF”分别对应你的字体是用于TextField还是用于FlashPlayer 10支持的FTE引擎。这两者是互斥的，不能选错。

如果在输出属性面板中选择的目标是Flash Player 9，那么在这里是不能选择嵌入方式的。

输出后的swf，使用下面的语法嵌入：

^?View Code ACTIONSCRIPT

[Embed(source="myFont.swf",fontFamily="04b_08"]
public var myFont:Class;

其中的 fontFamily就是双击嵌入的字体打开的的字体预览中显示的全名。例如，微软雅黑的fontFamily的值为 Microsoft YaHei。

这里要注意的是，不要使用这种错误的语法来嵌入字体：

^?View Code ACTIONSCRIPT

[Embed(source="myFont.swf",symbol="MyFont"]
public var myFont:Class;

这种语法一般会得到一个编译错误，因为 MyFont并不是一个Symbol，这种语法只能用于在Flash IDE中导出的MovieClip或者图像、声音等资源。

在纯AS3项目中嵌入字体

如果你和我一样讨厌Flash IDE的话，那不如直接在AS3代码中嵌入TTF字体好了，语法如下：

^?View Code ACTIONSCRIPT

[Embed(source="04b_08__.ttf",fontName="04b_08",embedAsCFF="false",unicodeRange="U+0020,U+0041-005A,U+0020,U+0061-007A,U+0030-0039,U+002E,U+0020-002F,U+003A-0040,U+005B-0060,U+007B-007E,U+0020-002F,U+0030-0039,U+003A-0040,U+0041-005A,U+005B-0060,U+0061-007A,U+007B-007E")] 
public var Font04b08:Class;
public var myFont:Class;

这一串代码代表的含义是：

使用传统方式（就是上面图2中提到的“传统”）嵌入字体名为04b_08的TTF字体中的英文、数字和标点符号，包含大小写。

来看看这四个常用参数的作用吧：

source 指定要嵌入的字体文件路径。还可以用 systemFont指定一个系统中安装的字体。这样的话就可以不需要 source参数了。
fontName 这个实际上就是 fontFamily 的别名。
embedAsCFF 如果不提供这个参数，默认就是true。所以，如果系统你嵌入的字体用于TextField，一定要将其设置为false。
unicodeRange 要嵌入的文本的范围。见下表：

嵌入字体范围：

大写字符 U+0020,U+0041-U+005A
小写字符 U+0020,U+0061-U+007A
数字 U+0030-U+0039,U+002E
标点符号 U+0020-U+002F,U+003A-U+0040,U+005B-U+0060,U+007B-U+007E
基本拉丁字符 U+0020-U+002F, U+0030-U+0039, U+003A-U+0040, U+0041-U+005A, U+005B-U+0060, U+0061-U+007A, U+007B-U+007E

当然，还有中文范围等等，详细的可以找到你本机的 FlexSDK/frameworks/flash-unicode-table.xml 看看就明白了。还可以参考Setting character ranges。

那么，怎样制作一个只有嵌入字体数据的swf文件呢？有两种方法：

第一种，使用下面的范例代码。下面的代码嵌入了两个字体，使用的范围和上面的例子一样。

有趣的是，如果你在嵌入字体的这个SWF文件中使用嵌入的字体（额……我知道有点拗口），你不需要注册这个字体。如果查看注册字体列表，你会发现它已经注册过了。运行下面的代码就知道了。

^?View Code ACTIONSCRIPT

package
{
import flash.display.Sprite;
import flash.text.Font;
public class fonts extends Sprite
{
    [Embed(source="04b_08__.ttf",fontName="04b_08",embedAsCFF="false",unicodeRange="U+0020,U+0041-005A,U+0020,U+0061-007A,U+0030-0039,U+002E,U+0020-002F,U+003A-0040,U+005B-0060,U+007B-007E,U+0020-002F,U+0030-0039,U+003A-0040,U+0041-005A,U+005B-0060,U+0061-007A,U+007B-007E")] 
    public var Font04b08:Class;
    [Embed(source="Frabk.ttf",fontFamily="Franklin Gothic Book",embedAsCFF="false",unicodeRange="U+0020,U+0041-005A,U+0020,U+0061-007A,U+0030-0039,U+002E,U+0020-002F,U+003A-0040,U+005B-0060,U+007B-007E,U+0020-002F,U+0030-0039,U+003A-0040,U+0041-005A,U+005B-0060,U+0061-007A,U+007B-007E")] 
    public var FontFrabk:Class;
 
    public function fonts()
    {
        var __fontArr:Array= Font.enumerateFonts(false);
        //Font.registerFont(myFont);
        for each(var __font:Font in __fontArr)
            trace(__font.fontName, __font.fontType);
    }
}
}

第二种，使用Flex SDK提供的fontswf工具，这个工具位于 FlexSDK/bin文件夹下，是JAVA开发的命令行工具。具体用法和参数与Embed类似，看Using the fontswf utility就清楚了。

载入外部的字体文件

当然，你不应该载入ttf文件。应该先使用上面介绍的方法把字体做成swf文件，然后载入。

使用Loader载入外部的swf文件后，需要获取到该swf中嵌入的字体的Class，然后使用 Font.registerFont 注册这个字体，注册成功后就可以使用了。

获取swf中嵌入的字体的Class，也有两种方法：

第一种，载入成功后，使用Loader.content获取到载入的swf的root，然后直接通过该swf中定义的public变量获取到类定义：

^?View Code ACTIONSCRIPT

    var __font:* = _loader.content;
    trace('04b08:', __font.Font04b08);
 
    Font.registerFont(__font.Font04b08);
    Font.registerFont(__font.FontFrabk);

第二种，载入成功后，使用 ApplicationDomain.getDefinition 获取嵌入的字体类，类的名称是“源文件类名_嵌入目标变量名称”：

^?View Code ACTIONSCRIPT

    var __fontClass:Class = _loader.contentLoaderInfo.applicationDomain.getDefinition("fonts_Font04b08") as Class;
    trace('class:',__fontClass);
    Font.registerFont(__fontClass);

在使用外部字体swf文件的时候，如果自身又被另一个swf载入，情况就变得非常复杂，需要设置应用程序域和系统安全域。简单的说，就是要遵循以下两条原则：

如果自己被父SWF载入，那么应用程序域就必须设置成当前域或者是子域才行

^?View Code ACTIONSCRIPT

    var __loaderContext:LoaderContext = new LoaderContext(true, ApplicationDomain.currentDomain);
    _loader.load(new URLRequest('fonts_local.swf'),  __loaderContext);

如果载入的字体swf与发起载入的swf不在一个网域，就需要将安全域设定为当前安全域

^?View Code ACTIONSCRIPT

    var __loaderContext:LoaderContext = new LoaderContext(true, ApplicationDomain.currentDomain, SecurityDomain.currentDomain);
    _loader.load(new URLRequest('fonts_local.swf'),  __loaderContext);

但是，如果子域和父域有同名包、同名类、同名方法，那么就要注意了，使用当前应用程序域或者子域会让你程序的结构变得一团糟，甚至可能会产生命名空间冲突。而这种冲突给出的运行时错误提示基本让你没法查出错误在哪里。

要理解这块的纠结之处，最好的办法是下载我的范例程序自已调试把！

Note: There is a file embedded within this post, please visit this post to download the file.
Note: There is a file embedded within this post, please visit this post to download the file.

FlashPlayer/AIR在new Vector(-1)的时候崩溃

zrong — Thu, 04 Aug 2011 09:50:38 +0000

source on github

试试这段代码：

^?View Code ACTIONSCRIPT

var __length:int = -1;
var __v:Vector.<String> = new Vector.<String>(__length);

如果你用Flash builder编译，不会显示任何错误。编译后的swf无法双击打开，或打开后立即退出。

如果你用编译的是AIR程序，程序运行后会立即崩溃，同时弹出下面的提示信息:

如果你用Flash IDE来编译，则会看到错误提示：

Error: Error #1000: 系统内存不足。
at Vector$object/set length()
at Vector$object()
at aaa_fla::MainTimeline/frame1()

这本来不是什么大问题，毕竟极少极少有人会使用 -1 这个值来作为Vector的length属性。

可是，起码给点提示好不好？起码让我不要找错方向！

测试平台：

FlashPlayer 10.3
Flash Builder 4.5.1
Flex SDK 4.5.1
AIR 1.

一个未完成的简单AS3 eval实现

zrong — Mon, 01 Aug 2011 03:48:09 +0000

本文源码(on github)：https://github.com/zrong/blog/blob/master/unfinished_as3_eval.md

AS3没有eval确实不方便，目前我所知有两种方法：

使用ActionScript 3 Eval Library来实现。但这个库比较大，debug编译越140KB。如果项目非常注重文件大小，则需要考虑；
如果swf部署在浏览器环境中，可以将eval交给Javascript来处理，然后获取Javascript的返回值即可。

我在工作中需要使用eval的地方，往往比较简单，且比较规律。这种情况下，完全可以自己写一些简单的逻辑来实现。

这个例子中的需求就很简单，是实现一个较为灵活的站位算法。我在外部配置文件中定位了12个站位坐标（包含xy值），人物进入界面后，基于这些站位点来站位。但由于舞台的大小是变化的，如果定义一个确定的值，无法根据舞台的大小进行变化。

如果让外部的配置文件中支持类似于 h/2 或者 w-100 这种语法，就非常灵活了。

这个实现仅支持一次运算，而且不支持单个的 w 这种类型的值，要获取 w，必须用 w+0 这种语法。但对当前的需求来说，足够了。

下面就是代码：

^?View Code ACTIONSCRIPT

/**
 * 站位容器宽高
 */
private var box_w:int = 600;
private var box_h:int = 400;
 
/**
 * 对传来的值进行运算，支持加减乘除的一次运算，变量支持w和h
 */
public function calculate($coord:*):int
{
     /*支持的运算符和变量
     例如：w-8 h/2 等等。格式必须是 1(w或h) 2(运算符) 3(数字)*/
    const reg:RegExp = /([w|h])([+|\-|*|\/]+)(\d+)/;
    var __num:Number = parseInt($coord);
    //如果可以解析，就返回解析后的值
    if(!isNaN(__num)) return __num;
    //如果该值不是字符串，就返回0
    if(!($coord is String)) return 0;
    var __coord:String = String($coord).toLowerCase();
    //不符合规则，返回0
    if(!reg.test(__coord)) return 0;
    //如果没有设置容器宽高，返回0
    if(box_w == 0 || box_h == 0) return 0;
    var __arr:Array = __coord.match(reg);
    //trace('arr:', __arr);
    var __box:int = __arr[1] == 'w' ? box_w : box_h;
    __num = int(__arr[3]);
    //加减乘除运算
    if(__arr[2] == '+')
        return __box + __num;
    else if(__arr[2] == '-')
        return __box - __num;
    else if(__arr[2] == '*')
        return __box * __num;
    return int(__box/__num);
}

AS3中正则表达式对反斜杠的替换

zrong — Thu, 14 Jul 2011 01:24:29 +0000

本文源码

一个有趣的小问题，下面的正则表达式能替换成功么？

^?View Code ACTIONSCRIPT

var __str:String = '1234\6789';
trace(__str.replace(/\\/g, '5'));

答案是：不能。trace出来的结果为：

[trace] 12346789

其实正则本身并没有写错，错在被替换的字符串。反斜杠“\”在AS3中是转义符，会将其后的任何值转换为本身，因此看到的字符串其实本身就是12346789，也就是没有反斜杠，当然无法搜索到。

直接trace(__str)，结果和上面的trace相同。

希望得到正确的结果，需要将字符串设置为：1234\\6789，我们看到的是两个反斜杠，而AS3认为它是一个反斜杠。

如果使用RegExp来建立正则，则需要使用4个反斜杠：

^?View Code ACTIONSCRIPT

var __str:String = '1234\\6789';
var __reg:RegExp = new RegExp('\\\\', '');
trace(__str.replace(__reg, '5'));

这种情况只在硬编码字符串的时候出现，而如果字符串出现在TextField中，从TextField.text中取出的字符串，本身就自动进行了转义，看到的一个反斜杠，其实是两个反斜杠。

附送一篇关于MXML中的正则表达式的文章：
MXML中正则表达式的expression需要转义

[转]Flash Player 执行模型之可变跑道

zrong — Fri, 08 Jul 2011 03:29:48 +0000

本文源码

原文地址：http://blogs.adobe.com/xwlin/2010/04/flash_player_101_-_adobe_max_2009_1.html
转载地址：http://blog.csdn.net/zlxluofeng/article/details/5516349
演讲人: Lee Thomason (lthomaso@adobe.com)
翻译: 林晓伟 (xwlin@adobe.com)

上一篇我们介绍了Flash Player的代码库是如何归并一体以及对Flash平台的后期开发产生的影响，在第二节里，我们将重点讨论Flash Player的体系结构及其对开发人员的影响。

理解执行模型

执行模型是指Flash Player在每一个帧周期中如何执行相应的指令操作。Flash Player后台事实上运行着n多线程，只是AS并没有给开发人员提供多线程编程模型。这意味着从概念上来讲我们要把Flash Player看做是单线程运行实体，有关这一单线程编程模型的优势/劣势的争论从未休止过，我不想对这一具有争议性的问题做过多评论，但请大家记住这一事实。

可变跑道(Elastic Racetrack)

可变跑道是Flash Player的帧执行模型，这个模型描述了在一帧的处理周期中，代码执行和帧渲染的工作是怎样彼此平衡的。Flash Player 9和AVM2对这一模型进行了一些改进，这一信息是基于对事件机制和渲染模型的研究总结出来的，完整的模型尚未被官方公布。

基本的跑道理论没有发生改变，在Flash Player执行一帧的周期里，前一部分时间用于执行代码，剩余时间用于渲染显示列表中的对象。每个执行阶段都可以根据实际需求增加执行时间来执行更多代码或做更多的渲染工作，而跑道的总长度也将相应增长。

在前一模型基础上发生改变的是每一阶段在一个微观周期里的样子以及他们怎样形成一帧。

AVM2是由Flash Player中一个叫做Marshal的元帅级组件所操控，Marshal负责将时间切割成Flash Player工作所依的基本时间片，在这里我希望澄清一下Flash Player的时间片跟swf文件运行时的帧速率没有任何关系，我们将最终看到Flash Player是如何将这些时间片合成为一帧。在Mac OS版Firefox中执行一个由Flex编译得来的swf文件，Marshal通常会将时间切割成19-20毫秒的时间片,时间片大小根据平台和浏览器的不同而存在差异.为方便我们接下来的讨论,我们假定时间片大小为20毫秒,也就是说Marshal每秒钟会产生不超过50个时间片，每个时间片中，五步可能的操作按如下顺序执行：

Player事件调度 – 比如Timer事件，鼠标事件，ENTER_FRAME事件，URLLoader事件等等。
用户代码执行 – 所有侦听上一步相应事件的代码被执行。
RENDER事件调度 – 在用户代码执行期间调用stage.invalidate()会触发这一特殊事件。
最后的用户代码执行 – 侦听上述第三步特殊事件的用户代码此时被执行。
Player更改显示列表。

Marshal如此反复的执行20毫秒时间片并在运行中决定下一步操作。一个时间片中执行的所有这些操作最终归纳为上述两段式跑道(代码执行，图像渲染)也就是我们所说的一帧。用户代码和失效操作填充在代码执行区，渲染操作填充在跑道的渲染区段。需要指出的是相关操作只能在Marshal预定的时间内发生，如果你的用户代码很短，那么Marshal仍然会在执行完用户代码后等待一段时间然后进入渲染阶段。

为了更好阐述哪些action被如何执行以及可变跑道如何被创建，请参考如下示例，分别描述了以5fps, 25fps和50fps帧速率工作的swf中时间片是如何被处理的。

以上示例可以看出，不同的帧速率下，一个帧周期中的可变跑道会执行不同操作，例如对于5fps的swf，每帧处理10个用户action，1个失效action，1个渲染action；帧速率25fps的swf，每帧处理2个用户action，1个失效action，1个渲染action；对于50fps的swf，每帧只能处理1个用户action，1个失效action，1个渲染action。需要指出的很重要的一点是，某些事件只可能能发生在某些特定的时间片里，比如，Event.ENTER_FRAME事件只能在某一帧的初始时间片中被调度。

一个时间片中代码部分和渲染部分都有可能过长而导致相应时间片大于20毫秒，这就是”可变”的含义，为了保证帧的播放速率仍然接近swf编译时设定的帧率，Marshal会选择丢掉一些时间片。
swf文件的播放速率不可能超过当前Flash Player切割时间片的速率，你可以为swf文件设定120fps的播放速率，但Flash最多可以按照50帧的速度播放(具体数值取决于当前系统的设置)。
代码的执行频率可能比swf的帧率更高，播放一个1fps的swf文件，播放一帧时间为1秒，也就是50个时间片，但在每个时间片里，都会有触发鼠标或计时器事件，尽管只有最后一个时间片才会渲染，另外你可以选择通过调用函数updateAfterEvent() 提前渲染，但只能在鼠标，计时器和键盘事件处理函数中调用。在这种情况下，Marshal会认为当前帧已结束并从下一个时间片起进入下一帧。最后，如果一个Sprite的外观属性比如width,height等发生变化而将鼠标从该Sprite上方掠过，Flash会进行强制渲染。
如果帧率不是每秒时间片数量的整数因子，那么该平台的渲染时间间隔将变得不固定，比如帧率20fps的swf运行在50个时间片每秒的系统上，Flash Player的行为将是每5个时间片播放两帧，那swf的渲染频率将是2-3-2-3-2-3(时间片)。

【原博主】
在9RIA上，有关于该文章的进一步讨论，主要是updateAfterEvent()到底能不能结束当前帧而进入下一帧，下面是讨论内容：

【jinni】
我一直对这篇文章的结论有质疑，根据我测试的结果，当调用updateAfterEvent()时，FP并不认为是一帧的结束，而只是单纯的重绘屏幕
例如你可以在一帧中点击20次鼠标＋updateAfterEvent()，并造成20次重绘事件(RENDER)，但对于Flash Player的帧事件(ENTER_FRAME)，只会触发一次。
换句话说，帧的运行次数和重绘屏幕的次数是没有任何关系的

【jinni】
其实有一个很简单的论证
很多Flash的逻辑依赖于ENTER_FRAME执行
如果调用updateAfterEvent()就会立即结束当前帧从并触发下一帧的话
那么这些Flash的运行逻辑就会加快了，这显然不合理
而事实上（根据我的测试），调用updateAfterEvent()只会触发RENDER事件和系统重绘
另外，Flex中的Mouse事件，默认会调用updateAfterEvent()来保证运行效果

【Aone】
我测试下来不会打断。不过确实有种可以打断帧的方法，就是给 stage.frameRate赋值，即便是stage.frameRate = stage.frameRate也会打断帧强制该帧结束。
测试代码如下：

^?View Code ACTIONSCRIPT

stage.frameRate = 1;  
var timer:Timer = new Timer(1);  
timer.addEventListener(TimerEvent.TIMER,onTimer);  
timer.start();  
addEventListener(Event.ENTER_FRAME,test);  
var old:int = getTimer();  
 
function test(e:Event):void {  
        trace(getTimer()-old);  
        old = getTimer();  
}  
 
function onTimer(e:TimerEvent):void {          
                //stage.frameRate = 1;  
        e.updateAfterEvent();  
        trace("timer");  
}

【jinni】
我所做的测试都是Mac和Win同时做的
事实证明updateAfterEvent()是不会造成帧的结束
而且，在实际情况中，updateAfterEvent()并不只是用户手动调用才会触发
Flash Player会根据需要来对自身进行强制重绘，一帧中可能触发数十次RENDER事件和重绘
而原文所描述的模型基于一个假设：“一帧之中用户事件代码会执行多次，但渲染事件代码和渲染过程只会执行一次。”就是不成立的。

【Aone】
updateAfterEvent()必须Timer触发或者鼠标事件还有键盘事件触发后才能正确重绘。
不过呢… 鼠标和键盘就算不注册侦听在某些情况下也会自动updateAfterEvent()来强制渲染。

【jinni】
我和Ted讨论了一下,这是他的回复：

Yes you can call updateAfterEvent over and over between standard renders. You basically inject a partial render in the code execution side of the racetrack and elongate it.
I would love to see AS have full render control as a playermode in FP11. If set there are no automatic renders and the developer must call render for all visual changes to occur.
是的，你可以在每次标准RENDER（即原文中的Last slice’s render）之间调用多次updateAfterEvent（并进行重绘），相当于你在跑道一圈中代码执行的阶段”注入”了部分渲染过程并延长了整个跑道。

其实我很希望看到Flash Player 11可以在某种模式下给开发者完整的渲染控制。在这种情况下开发者必须主动调用API来实现屏幕重绘。

我想问题其实已经比较清楚了，文中跑道模型描述的只是其中一种形态，很多时候，渲染和用户代码的调用在一帧的过程中，是穿插进行的，而不是简单的先执行用户代码，最后渲染

FocusEvent与buttonMode的关系

zrong — Mon, 27 Jun 2011 14:24:34 +0000

本文源码

这两个家伙有关系么？

当然有，而且还挺紧密的。

它们之间的关系就是：

如果一个Sprite不开启buttonMode，那么就不会有FocusEvent事件发出

这关系说起来挺简单的，但是你若是不知道，而且还急着用，说不定会让你发疯……（我就疯了一次）

当然，TextField虽然没有buttonMode，也会有FocusEvent。

那么SimpleButton会如何？我没试，懒得试了……

把下面的代码中的 _sprite.buttonMode = true; 一行注释掉，可以看到（或者说看不到？）效果。

^?View Code ACTIONSCRIPT

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.FocusEvent;
import flash.events.MouseEvent;
import flash.text.TextField;
 
public class Focus extends Sprite
{
	public function Focus()
	{
		getSprite();
		getSprite(200, 0);
 
		var _tf:TextField = new TextField();
		_tf.type = 'input';
		_tf.border = true;
		_tf.x = 200;
		_tf.y = 200;
		_tf.addEventListener(FocusEvent.FOCUS_IN, handler_focusin);
		_tf.addEventListener(FocusEvent.FOCUS_OUT, handler_focusout);
		addChild(_tf);
 
	}
 
	private var _sprite:Sprite;
 
	private function getSprite($x:int=0, $y:int=0):Sprite
	{
		var _sprite:Sprite = new Sprite();
		_sprite.graphics.beginFill(0);
		_sprite.graphics.drawRect(0,0,100,100);
		_sprite.graphics.endFill();
		_sprite.x = $x;
		_sprite.y = $y;
		_sprite.useHandCursor = true;
		_sprite.buttonMode = true;
		this.addChild(_sprite);
		_sprite.addEventListener(FocusEvent.FOCUS_OUT, handler_focusout);
		_sprite.addEventListener(FocusEvent.FOCUS_IN, handler_focusin);
		_sprite.addEventListener(MouseEvent.CLICK, handler_click);
		return _sprite;
	}
 
	private function handler_focusout(evt:FocusEvent):void
	{
		trace('focusout,target:', evt.target, ',relatedTarget:', evt.relatedObject);
	}
 
	private function handler_focusin(evt:FocusEvent):void
	{
		trace('focusin,target:', evt.target, ',relatedTarget:', evt.relatedObject);
	}
 
	private function handler_click(evt:MouseEvent):void
	{
		trace('click');
	}
}
}