FMS中变量的作用域-之二

作者: zrong 日期: 2008-08-27 发表评论 (0) 查看评论

本站原创文章，转载请注明： 转载自zrong's Blog，原文 FMS中变量的作用域-之二，欢迎使用文章源码进行转载。

本站转载文章会标明[转]，转载请注明原始作者文章地址。

在FMS中变量的作用域一文中，我曾经研究过这个问题，得到的结论是：

保存在Client中的变量对于每个客户机都是不同的，application中的变量则可以在instance中共享，instance之间不能共享变量。（使用一些变通的方法是可以的）

这里要讨论的，是FMS中到底有哪几种变量作用域（注：这里不讨论函数内部的变量），对于FMS代码中的自定义类，变量的作用域又是什么呢？在FMS的自定义类中，如何调用其他作用域的变量？

首先看一段代码：User.asc

^?View Code ACTIONSCRIPT

function User()
{
	varInGlobal = 0;
	this.varInUser = 0;
	User.varStatic = 0;
	application.varInApp = 0;
}
 
User.prototype.userTrace = function()
{
	trace('=====================User.prototype.userTrace');
	trace('varInGlobal:' + varInGlobal);
	trace('this.varInUser:' + this.varInUser);
	trace('user.varInUser:' + user.varInUser);
	trace('User.varStatic:' + User.varStatic);
	trace('application.varInApp:' + application.varInApp);
}
 
User.userTraceStatic = function()
{
	trace('=====================User.userTraceStatic');
	trace('varInGlobal:' + varInGlobal);
	trace('this.varInUser:' + this.varInUser);
	trace('user.varInUser:' + user.varInUser);
	trace('User.varStatic:' + User.varStatic);
	trace('application.varInApp:' + application.varInApp);
}

这段代码写在User.asc文件中，与main.asc处于同一个FMS程序var_test下。User是一个自定义对象，在建立User对象的时候，建立了4个变量，第1个没有用任何的修饰符，第2个用this修饰符，第3个用User修饰符，第4个application修饰符。
另外，建立了两个方法，一个是User类的静态方法userTraceStatic，另一个是实例方法userTrace，两个方法中的代码相同，都是显示这4个变量的值。其中对varInUser变量采用不同的引用方式显示了两遍。

main.asc的内容如下：

^?View Code ACTIONSCRIPT

load("User.asc");
 
application.onAppStart = function()
{
	application.registerClass("User", User);
	user = new User();
}
 
application.onConnect = function(client)
{
	trace("登录成功！");
	application.acceptConnection(client);
	varInGlobal ++;
	user.varInUser += 10;
	User.varStatic += 100;
	application.varInApp += 1000;
 
	globalTrace();
	user.userTrace();
	User.userTraceStatic();
}
 
function globalTrace()
{
	trace('=====================globalTrace');
	trace('varInGlobal:' + varInGlobal);
	trace('user.varInUser:' + user.varInUser);
	trace('User.varStatic:' + User.varStatic);
	trace('application.varInApp:' + application.varInApp);
}

这段代码中定义了一个全局函数globalTrace，仍然是显示这4个变量的值。在onConnect事件中，改变这4个变量的值，并调用3个显示值的函数。

Flex 客户端代码：

^?View Code XML

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical">
	<mx:Script>
		<![CDATA[
			import flash.net.NetConnection;
 
			private var nc:NetConnection;
 
			private function ncClick():void
			{
				nc = new NetConnection();
				nc.addEventListener(NetStatusEvent.NET_STATUS, ncHandler);
				nc.connect('rtmp:/var_test/1');
			}
 
			private function ncHandler(evt:NetStatusEvent):void
			{
				trace(evt.info.code)
			}
		]]>
	</mx:Script>
	<mx:Button id="ncBTN" label="nc" click="ncClick()"/>
</mx:Application>

执行结果如下（FMS Admin Console中的显示）：

登录成功！
=====================globalTrace
user.varInUser:10
varInGlobal:1
User.varStatic:100
application.varInApp:1000
=====================User.prototype.userTrace
varInGlobal:1
this.varInUser:10
user.varInUser:10
User.varStatic:100
application.varInApp:1000
=====================User.userTraceStatic
varInGlobal:1
this.varInUser:undefined
user.varInUser:10
User.varStatic:100
application.varInApp:1000

由此可见，没有使用任何标示符定义的变量varInGlobal，确实是一个全局变量，不但在自定义类中，还是在其他事件中，都是可以直接访问的。application中的变量其实和user实例中的变量是一样的，必须指定属主才能访问。而User中定义的变量和方法都是静态的，静态的方法无法使用this关键字访问实例中的变量，但可以通过全局变量user访问。

FMS中变量的作用域-之二（源文件） (1.9 KiB, 426 hits)